回到拆分地址上，那第一个，就是查找省这个字位于地址中的位置。

=FIND("省",A2)

如此得到省的位置后，我们便可以通过left函数，直接提取出省名称。

=LEFT(A2,FIND("省",A2))

前面的是不是都很成功，但是最后一个自治区，就识别不出来了。

主要是我国的行政区划分，不是所有的省级行政区都是省结尾的，还包括有市、区。

所以这里，我们需要通过数组公式，来一次性提取出省、市、区这三个字在地址中的位置。

数组公式如下：

=FIND({"省","市","区"},A2)

「注意数组公式，需要按照数组公式输入方法使用」

数组公式使用方法

需提前选中承接数组公式结果的单元格区域

再输入数组公式

最后需要按数组确认键 CTRL+SHIFT+回车 确认公式

目前只是把地址中省市区出现的位置找到了，还需要对数字进行对比，最小的那个，代表最先出现，也就是省级行政单位的位置。

所以我们使用min函数对其嵌套，得到最小位置数，再使用left函数提取，就能正确获得一级行政区名称。

但是由于min函数不能统计包含#VALUE!的错误值数据，所以我们在find公式中的地址参数那里，手动拼接一个省市区字符串，使其不管怎么样，都不会返回错误值。确保min函数正确运行。

数组公式如下：

=LEFT(A2,MIN(FIND({"省","市","区"},A2&"省市区")))

至此第一个省级名称，提取完毕。

如果将原地址中的省级名称去除，那么剩下的地址中，就只包含地级和县级行政区地址信息。

使用substitute函数，就可以替换字符串中的指定字符为空，也就是替换为""。

函数公式如下：

=SUBSTITUTE(A2,B2,"")

我们借用了刚刚提取的省级名称，生成了新的地址，基于这个地址我们采用同样的方法提取地级行政区名称。

只需要把省级行政区的公式中的地址A2全部替换成上面的subtitute函数公式，再把对应的地级行政区的后缀，市、区、州、盟，全部修改，就可以了。

最终的数组公式如下：

=LEFT(SUBSTITUTE(A2,B2,"")&"市区州盟",MIN(FIND({"市","区","州","盟"},SUBSTITUTE(A2,B2,"")&"市区州盟")))

最后一个直接使用substitute函数替换即可。

数组公式如下：

=SUBSTITUTE(A2,B2&C2,"")

如果你不想用上面这么长的公式，又或者地址信息没有这么完整，存在不清晰的问题！！

「那就使用方方格子插件来完成地址提取，速度飞快。」

操作路径：方方格子-高级文本处理更多-提取地址-选择地址范围-确定-点击结果存放单元格-确认

最终结果如下图，几秒钟就搞定了。

即使地址不是特别规范，也能大概匹配拆分出来。

当然，最终还需要仔细检查一下是否存在拆分出错的情况。

如下图数据所示：

文本中用-分隔各个信息，其中第二个是产品名称，最后一个是核销状态。

如果是比较规范的数据，就可以先手动提取一行，如下图：

然后按快捷键CTRL+E，智能拆分提取，就能提取出对应的数据。

但是，这个案例，CTRL+E没法很好的拆分出来，比如产品名称，此时可以选择使用函数公式，将产品名称和核销状态提取出来。

提取产品名称：

=MID(A2,FIND("-",A2)+1,FIND("-",A2,    FIND("-",A2)+1)-FIND("-",A2)-1    )

提取最后一个核销状态：

=TRIM(RIGHT(SUBSTITUTE(A2,"-",    REPT(" ",LEN(A2))    ),LEN(A2)))